@ECHO OFF
> CON ECHO.
> CON ECHO IEVer.bat,  Version 2.00 for Windows NT 4 / 2000
> CON ECHO Logs Internet Explorer version (only once each day)
> CON ECHO.
> CON ECHO Usage:  IEVER
> CON ECHO.
> CON ECHO Note:   Requires REG.EXE, native in Windows 2000 or
> CON ECHO         available in the Windows NT 4 Resource Kits
> CON ECHO.
> CON ECHO Written by Rob van der Woude
> CON ECHO http://www.robvanderwoude.com

:: Keep variables local
SETLOCAL

:: Check Windows version
IF NOT "%OS%"=="Windows_NT" GOTO End

:: Abort if any command line argument was passed
IF NOT "%~1"=="" GOTO End

:: Check version of REG.EXE
FOR /F "tokens=*" %%A IN ('REG.EXE 2^>^&1 ^| FIND.EXE "version"') DO FOR %%B IN (%%A) DO SET RegVer=%%B
FOR /F "tokens=1 delims=." %%A IN ('ECHO.%RegVer%') DO SET RegVer=%%A

:: Define log file and directory here
SET LogFile=\\ourserver\data\logs\IEVer.log
SET LogFile=IEVer.log

:: Check today's date
FOR /F "tokens=2-4* delims=- " %%A IN ('DATE/T') DO SET CurDate=%%C%%B%%A

:: Read IE version from registry and store it in a variable
IF %RegVer% GEQ 2 (
	FOR /F "tokens=2*" %%A IN ('REG.EXE QUERY "HKEY_LOCAL_MACHINE\Software\Microsoft\Internet Explorer" /V "Version" ^| FIND "REG_SZ"') DO SET IEVer=%%B
) ELSE (
	FOR /F "tokens=1*" %%A IN ('REG.EXE QUERY "HKEY_LOCAL_MACHINE\Software\Microsoft\Internet Explorer\Version" ^| FIND "REG_SZ"') DO FOR %%C IN (%%B) DO SET IEVer=%%C
)
IF "%IEVer%"=="" GOTO End

:: Display result
> CON ECHO.
> CON ECHO %ComputerName%	%CurDate%	%UserName%	%IEVer%

:: Check if a log entry for this computer was made already today
IF NOT EXIST %LogFile% GOTO Log
TYPE %LogFile% | FIND "%ComputerName%	%CurDate%" >NUL
IF NOT ERRORLEVEL 1 GOTO End

:: Log result
:Log
>> %LogFile% ECHO %ComputerName%	%CurDate%	%UserName%	%IEVer%

:: End program
:End
ENDLOCAL
GOTO:EOF