@ECHO OFF
SET Version=1.03
ECHO.
ECHO Pict_NT.bat, Version %Version% for Windows NT
ECHO Displays all GIFs, JPEGs and PNGs in a HTML file.
ECHO.
ECHO Written by Rob van der Woude
ECHO http://www.robvanderwoude.com
ECHO.

IF NOT "%OS%"=="Windows_NT" GOTO End
IF NOT EXIST *.GIF IF NOT EXIST *.JPG IF NOT EXIST *.JPEG IF NOT EXIST *.PNG GOTO End

SETLOCAL
SET OutFile="%~n0.html"
>  %OutFile% ECHO ^<html^>
>> %OutFile% ECHO ^<head^>
>> %OutFile% ECHO ^<title^>All GIFs, JPGs and PNGs found in directory %CD%^</title^>
>> %OutFile% ECHO ^</head^>
>> %OutFile% ECHO ^<body^>
>> %OutFile% ECHO ^<div align="center"^>
>> %OutFile% ECHO ^<h1^>All GIFs, JPGs and PNGs^</h1^>
>> %OutFile% ECHO ^<h2^>found in directory^</h2^>
>> %OutFile% ECHO ^<h2^>%CD%^</h2^>
FOR %%A IN (*.GIF *.JPG *.JPEG *.PNG) DO (
	>> %OutFile% ECHO ^<p^>^&nbsp;^</p^>
	>> %OutFile% ECHO ^<p^>^<img src="%%~nxA"^>^</p^>
	>> %OutFile% ECHO ^<p^>%%~nxA^</p^>
)
>> %OutFile% ECHO ^<p^>^&nbsp;^</p^>
>> %OutFile% ECHO ^<p^>This HTML page was generated using^</p^>
>> %OutFile% ECHO ^<p^>PICT_NT.BAT,  Version %Version%^</p^>
>> %OutFile% ECHO ^<p^>Written by Rob van der Woude^</p^>
>> %OutFile% ECHO ^<p^>^<a href="http://www.robvanderwoude.com"^>http://www.robvanderwoude.com^</a^>^</p^>
>> %OutFile% ECHO ^</div^>
>> %OutFile% ECHO ^</body^>
>> %OutFile% ECHO ^</html^>
START "Pictures.bat" %OutFile%
ENDLOCAL
GOTO:EOF

:End
SET Version=