Break On

"Latest version of Revo Uninstaller Freeware : " + GetRevoVersion( "Free" ) + @CRLF
"Latest version of Revo Uninstaller Pro      : " + GetRevoVersion( "Pro"  )


Function GetRevoVersion( $myType )
; This function returns the latest Revo Uninstaller
; version as string by reading Revo's download page.
; If an error occurs, the returned version will be "0".
; Written by Rob van der Woude
; http://www.robvanderwoude.com
	; Initial return string, in case an error occurs
	$strRevoVersion = "0"
	; Use WinHTTP to read the text from Revo's download page
	$objHTTP = CreateObject( "WinHttp.WinHttpRequest.5.1" )

	If UCase( $myType ) = "PRO"
		$RC = $objHTTP.Open( "GET", "http://www.revouninstaller.com/revo_uninstaller_pro_full_version_history.html", 0 )
	Else
		$RC = $objHTTP.Open( "GET", "http://www.revouninstaller.com/revo_uninstaller_full_version_history.html", 0 )
	EndIf
	$strUserAgent = "Mozilla/5.0 (Windows; U; Windows NT 5.1; en-US; rv:1.9.0.3) Gecko/2008092417 Firefox/3.0.3"
	$RC = $objHTTP.SetRequestHeader( "UserAgent", $strUserAgent )
	$RC = $objHTTP.Send
	If $objHTTP.Status = 200
		; If the page was returned, use a regular expression
		; to extract Foxit Reader's current version number
		$strHTML = $objHTTP.ResponseText
		If UCase( $myType ) = "PRO"
			$strPattern = "Revo Uninstaller Pro version "
		Else
			$strPattern = "Revo Uninstaller Freeware version "
		EndIf
		$strVersion = Trim( SubStr( $strHTML, InStr( $strHTML, $strPattern ) + Len( $strPattern ), 7 ) )
		$strVersion = Left( $strVersion, InStr( $strVersion, "<" ) - 1 )
	EndIf
	; Return the result
	$GetRevoVersion = $strVersion
EndFunction