@ECHO OFF
REM * Ask for USeR INPUT and store it in variable USRINPUT
REM * OS/2 version
REM * Written by Rob van der Woude

SET USRINPUT=

REM * Turn on ANSI key translation (translate Enter
REM * key to F6+Enter sequence) and ask for input:
ECHO Enter one word only . . .

REM * Copy entered text to temporary file:
COPY CON %TEMP%.\~USRINP.TMP

REM * Turn off ANSI key translation and clear irrelevant screen output:
ECHO 

REM * Add empty line to temporary file. The empty line
REM * will be used to stop DATE asking for new date.
ECHO.>> %TEMP%.\~USRINP.TMP
ECHO.>> %TEMP%.\~USRINP.TMP

REM * Create a temporary batch file that will store the
REM * entered text into the environment variable USRINPUT:
TYPE %TEMP%.\~USRINP.TMP | DATE | FIND "):" > %TEMP%.\~USRINP.CMD

REM * Create more temporary batch files. Add
REM * more command line parameters if necessary,
REM * as in: ECHO SET USRINPUT=%%3 %%4 %%5 %%6 %%7 %%8 %%9>CURRENT.CMD
ECHO SET USRINPUT=%%3>CURRENT.CMD

REM * VOER.CMD and TYP.CMD are replacements for CURRENT.CMD for Dutch
REM * OS/2 versions; add your own language versions if necessary:
ECHO SET USRINPUT=%%6>VOER.CMD
ECHO SET USRINPUT=%%4>TYP.CMD

REM * This temporary batch file now sets the variable USRINPUT:
CALL %TEMP%.\~USRINP.CMD

REM * Display the result:
ECHO You typed: %USRINPUT%
ECHO.
PAUSE

REM * Finally, clean up the mess of temporary files:
FOR %%A IN (%TEMP%.\~USRINP.CMD %TEMP%.\~USRINP.TMP VOER.CMD TYP.CMD CURRENT.CMD) DO DEL %%A