Rob van der Woude's Scripting Pages
Powered by GeSHi

Source code for software.hta

(view source code of software.hta as plain text)

  1. <!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.01//EN" "http://www.w3.org/TR/html4/strict.dtd">
  2. <html>
  3. <head>
  4. <title>Software Inventory</title>
  5.  
  6. <HTA:APPLICATION
  7.   APPLICATIONNAME="Software Inventory"
  8.   ID="SoftInv"
  9.   VERSION="3.02"
  10.   ICON="msiexec.exe"
  11.   SINGLEINSTANCE="yes"
  12.   WINDOWSTATE="maximize"/>
  13.  
  14. <style type="text/css">
  1. body {
  2. 	font: 12pt arial,sans-serif;
  3. 	color: white;
  4. 	background-color: black;
  5. 	filter: progid:DXImageTransform.Microsoft.Gradient(Gradienttype=0, StartColorStr='#0000FF', EndColorStr='#000000');
  6. 	padding: 0;
  7. 	margin: 0;
  8. 	height:
  9. }
  10.  
  11. a {
  12. 	color: red;
  13. }
  14.  
  15. td
  16. {
  17. 	text-align: left;
  18. }
  19.  
  20. .Button
  21. {
  22. 	width: 12em;
  23. 	margin: 3px 1em 3px 1em;
  24. }
  25.  
  26. .Center
  27. {
  28. 	margin-left: auto;
  29. 	margin-right: auto;
  30. 	text-align: center;
  31. }
  32.  
  33. .Left
  34. {
  35. 	text-align: left;
  36. }
  37.  
  38. .Red
  39. {
  40. 	color: red;
  41. }
  42.  
  43. .Right
  44. {
  45. 	text-align: right;
  46. }
  47.  
  48. .White
  49. {
  50. 	color: white;
  51. }
  1. </style>
  2.  
  3. </head>
  4.  
  5. <script language="VBScript">
  1. Option Explicit
  2.  
  3. Const CopyRights = ""
  4.  
  5. ' Global variables
  6. Dim clrBgErr, clrTxtErr
  7. Dim intUpdateSize, intVerMsgSize, intWindowHeight, intWindowWidth
  8. Dim strAppName, strAppVer, strComputer, strFileNames
  9.  
  10.  
  11. clrBgErr      = "#FF0000"
  12. clrTxtErr     = "#FFFFFF"
  13. ' Global variables, used by CheckUpdate subroutine
  14. strAppName    = SoftInv.ApplicationName
  15. strAppVer     = SoftInv.Version
  16. strFileNames  = "software"
  17.  
  18.  
  19. Sub CheckUpdate( )
  20. 	Dim intAnswer, intButtons, lenLatestVer, strLatestver, strPrompt, strTitle, wshShell
  21.  
  22. 	' Change mouse pointer to hourglass while checking for update
  23. 	document.body.style.cursor = "wait"
  24.  
  25. 	Set wshShell  = CreateObject( "WScript.Shell" )
  26. 	strLatestVer  = TextFromHTML( "http://www.robvanderwoude.com/updates/" & strFileNames & ".txt" )
  27.  
  28. 	If strAppVer <> strLatestver Then
  29. 		' Clear the IE cache
  30. 		wshShell.Run "RUNDll32.EXE InetCpl.cpl,ClearMyTracksByProcess 8", 7, True
  31. 		' Try again, read the latest version info from the web
  32. 		strLatestver = TextFromHTML( "http://www.robvanderwoude.com/updates/" & strFileNames & ".txt" )
  33. 	End If
  34.  
  35. 	lenLatestVer  = Len( strLatestVer )
  36. 	If lenLatestVer = 4 Then
  37. 		intButtons = vbYesNoCancel + vbApplicationModal + vbInformation
  38. 		If strLatestVer < strAppVer Then
  39. 			strTitle  = "Unofficial version"
  40. 			strPrompt = "You seem to be using a pre-release version (" & strAppVer & ") of the " & strAppName & "." _
  41. 			          & vbCrLf & vbCrLf _
  42. 			          & "The latest official release is " & strLatestver _
  43. 			          & vbCrLf & vbCrLf _
  44. 			          & "Do you want to download the latest official version?"
  45. 			intAnswer = MsgBox( strPrompt, intButtons + vbDefaultButton2, strTitle )
  46. 			If intAnswer = vbYes Then
  47. 				wshShell.Run "http://www.robvanderwoude.com/" & strFileNames & ".php", 3, False
  48. 			End If
  49. 		End If
  50. 		If strLatestVer > strAppVer Then
  51. 			strTitle  = "Old version"
  52. 			strPrompt = "You are using version " & strAppVer & " of the " & strAppName & "." _
  53. 			          & vbCrLf & vbCrLf _
  54. 			          & "The latest official release is " & strLatestver _
  55. 			          & vbCrLf & vbCrLf _
  56. 			          & "Do you want to download the latest official version?"
  57. 			intAnswer = MsgBox( strPrompt, intButtons, strTitle )
  58. 			If intAnswer = vbYes Then
  59. 				wshShell.Run "http://www.robvanderwoude.com/" & strFileNames & ".php", 3, False
  60. 			End If
  61. 		End If
  62. 	End If
  63.  
  64. 	Set wshShell = Nothing
  65.  
  66. 	' Change mouse pointer back to default
  67. 	document.body.style.cursor = "default"
  68. End Sub
  69.  
  70.  
  71. Sub CopyClipboard
  72. 	Document.ParentWindow.ClipboardData.SetData "text", ResultsHiddenText.Value
  73. End Sub
  74.  
  75.  
  76. Sub EditQuery
  77. 	ComputerNameTextBox.Disabled      = False
  78. 	ResultsTextArea.Value             = ""
  79. 	ResultsHiddenText.Value           = ""
  80. 	FilterNameTextBox.Disabled        = False
  81. 	FilterVendorTextBox.Disabled      = False
  82. 	FilterDateTextBox.Disabled        = False
  83. 	SPTextBox.Disabled                = False
  84. 	CopyButton.Disabled               = True
  85. 	EditButton.Disabled               = True
  86. 	PasteButtonPC.Disabled            = False
  87. 	PasteButtonNameFilter.Disabled    = False
  88. 	PasteButtonVendorFilter.Disabled  = False
  89. 	PasteButtonDateFilter.Disabled    = False
  90. 	RunButton.Disabled                = False
  91. 	ResetButton.Disabled              = False
  92. 	ComputerNameTextBox.Focus( )
  93. End Sub
  94.  
  95.  
  96. Function GetComputerName( )
  97. 	Dim colItems, objItem, objWMIService
  98.  
  99. 	On Error Resume Next
  100.  
  101. 	Set objWMIService = GetObject( "winmgmts://./root/cimv2" )
  102. 	If Err Then
  103. 		ComputerNameTextBox.Style.backgroundColor = clrBgErr
  104. 		ComputerNameTextBox.Style.Color           = clrTxtErr
  105. 		ComputerNameTextBox.Focus( )
  106. 		Err.Clear
  107. 		On Error GoTo 0
  108. 		EditQuery( )
  109. 		Exit Function
  110. 	End If
  111.  
  112. 	Set colItems = objWMIService.ExecQuery( "Select * from Win32_ComputerSystem" )
  113. 	If Err Then
  114. 		ComputerNameTextBox.Style.backgroundColor = clrBgErr
  115. 		ComputerNameTextBox.Style.Color           = clrTxtErr
  116. 		ComputerNameTextBox.Focus( )
  117. 		Err.Clear
  118. 		On Error GoTo 0
  119. 		EditQuery( )
  120. 		Exit Function
  121. 	End If
  122.  
  123. 	For Each objItem in colItems
  124. 		strComputer = objItem.Name
  125. 	Next
  126.  
  127. 	On Error GoTo 0
  128.  
  129. 	ComputerNameTextBox.Value = strComputer
  130. 	GetComputerName           = strComputer
  131. End Function
  132.  
  133.  
  134. Sub Inventory
  135. 	Dim strDateFilter, strSortDate
  136.  
  137. 	' Change mouse pointer to hourglass while checking for update
  138. 	Document.Body.Style.Cursor   = "wait"
  139.  
  140. 	ComputerNameTextBox.Style.backgroundColor = ""
  141. 	ComputerNameTextBox.Style.Color           = ""
  142.  
  143. 	strComputer = Trim( UCase( ComputerNameTextBox.Value ) )
  144. 	If strComputer = "" Or strComputer = "." Then strComputer = GetComputerName( )
  145.  
  146. 	strSortDate    = Year( Now( ) ) & Right( "0" & Month( Now( ) ), 2 ) & Right( "0" & Day(   Now( ) ), 2 )
  147. 	strDateFilter  = Trim( FilterDateTextBox.Value )
  148. 	If strDateFilter <> "" Then
  149. 		If IsNumeric( strDateFilter ) = False Then
  150. 			MsgBox "The date filter format should be YYYYMMDD", vbInformation, "Date Filter Error"
  151. 			FilterDateTextBox.Focus( )
  152. 			Exit Sub
  153. 		ElseIf strDateFilter < 19800101 Or strDateFilter > strSortDate Then
  154. 			MsgBox "The date filter format should be YYYYMMDD", vbInformation, "Date Filter Error"
  155. 			FilterDateTextBox.Focus( )
  156. 			Exit Sub
  157. 		End If
  158. 	End If
  159.  
  160. 	WinVer( strComputer )
  161.  
  162. 	ComputerNameTextBox.ReadOnly     = True
  163. 	FilterNameTextBox.ReadOnly       = True
  164. 	FilterVendorTextBox.ReadOnly     = True
  165. 	FilterDateTextBox.ReadOnly       = True
  166. 	PasteButtonPC.disabled           = True
  167. 	PasteButtonNameFilter.Disabled   = True
  168. 	PasteButtonVendorFilter.Disabled = True
  169. 	PasteButtonDateFilter.Disabled   = True
  170. 	RunButton.Disabled               = True
  171. 	ResetButton.Disabled             = True
  172.  
  173. 	ResultsTextArea.Value            = "WMI query in progress, please wait . . ."
  174.  
  175. 	window.setTimeout "ListSoftware( )", 10
  176. End Sub
  177.  
  178.  
  179. Sub ListSoftware( )
  180. 	Dim arrProgram, arrSoftware
  181. 	Dim i
  182. 	Dim colItems, objItem, objWMIService
  183. 	Dim strCsv, strDateFilter, strKey, strNameFilter, strOutput, strSortDate, strVendorFilter, strValue
  184.  
  185. 	strNameFilter   = Trim( FilterNameTextBox.Value )
  186. 	strVendorFilter = Trim( FilterVendorTextBox.Value )
  187. 	strDateFilter   = Trim( FilterDateTextBox.Value )
  188. 	strSortDate     = Year( Now( ) ) & Right( "0" & Month( Now( ) ), 2 ) & Right( "0" & Day(   Now( ) ), 2 )
  189.  
  190. 	ResultsHiddenText.Value = "Computer:"      & vbTab _
  191. 	                        & "Name:"          & vbTab _
  192. 	                        & "Version:"       & vbTab _
  193. 	                        & "Vendor:"        & vbTab _
  194. 	                        & "Install Date:"  & vbTab _
  195. 	                        & "Package Cache:" & vbTab _
  196. 	                        & "ID:"            & vbCrLf
  197.  
  198. 	Set arrSoftware   = CreateObject( "System.Collections.Sortedlist" )
  199.  
  200. 	On Error Resume Next
  201.  
  202. 	Set objWMIService = GetObject( "winmgmts://" & strComputer & "/root/CIMV2" )
  203. 	If Err Then
  204. 		ComputerNameTextBox.Style.backgroundColor = clrBgErr
  205. 		ComputerNameTextBox.Style.Color           = clrTxtErr
  206. 		ComputerNameTextBox.Focus( )
  207. 		Err.Clear
  208. 		On Error GoTo 0
  209. 		EditQuery( )
  210. 		Exit Sub
  211. 	End If
  212.  
  213. 	Set colItems = objWMIService.ExecQuery( "SELECT * FROM Win32_Product" )
  214. 	If Err Then
  215. 		ComputerNameTextBox.Style.backgroundColor = clrBgErr
  216. 		ComputerNameTextBox.Style.Color           = clrTxtErr
  217. 		ComputerNameTextBox.Focus( )
  218. 		Err.Clear
  219. 		On Error GoTo 0
  220. 		EditQuery( )
  221. 		Exit Sub
  222. 	End If
  223.  
  224. 	For Each objItem In colItems
  225. 		If InStr( 1, objItem.Name, strFilter, vbTextCompare ) > 0 Then
  226. 			strKey   = objItem.Name & " " & objItem.Version
  227. 			strValue = objItem.Name & vbTab & objItem.Version & vbTab & objItem.Vendor & vbTab & objItem.InstallDate & vbTab & objItem.PackageCache & vbTab & objItem.IdentifyingNumber
  228. 			If arrSoftware.ContainsKey( strKey ) Then
  229. 				Do While arrSoftware.ContainsKey( strKey )
  230. 					strKey = strKey & " 0"
  231. 				Loop
  232. 			End If
  233. 			arrSoftware.Add strKey, strValue
  234. 		End If
  235. 	Next
  236.  
  237. 	On Error Goto 0
  238.  
  239. 	ResultsTextArea.Value = ""
  240.  
  241. 	For i = 0 To arrSoftware.Count - 1
  242. 		arrProgram = Split( arrSoftware.GetByIndex(i), vbTab )
  243. 		If InStr( 1, arrProgram(0), strNameFilter, vbTextCompare ) > 0 And InStr( 1, arrProgram(2), strVendorFilter, vbTextCompare ) > 0 And arrProgram(3) >= strDateFilter Then
  244. 			strOutput  = "Name          :  " & arrProgram(0) & vbCrLf _
  245. 			           & "Version       :  " & arrProgram(1) & vbCrLf _
  246. 			           & "Vendor        :  " & arrProgram(2) & vbCrLf _
  247. 			           & "Install Date  :  " & arrProgram(3) & vbCrLf _
  248. 			           & "Package Cache :  " & arrProgram(4) & vbCrLf _
  249. 			           & "ID            :  " & arrProgram(5) & vbCrLf & vbCrLf
  250. 			ResultsTextArea.Value = ResultsTextArea.Value & strOutput
  251. 			strCsv     = strComputer   & vbTab _
  252. 			           & arrProgram(0) & vbTab _
  253. 			           & arrProgram(1) & vbTab _
  254. 			           & arrProgram(2) & vbTab _
  255. 			           & arrProgram(3) & vbTab _
  256. 			           & arrProgram(4) & vbTab _
  257. 			           & arrProgram(5) & vbCrLf
  258. 			ResultsHiddenText.Value = ResultsHiddenText.Value & strCsv
  259. 		End If
  260. 	Next
  261. 	CopyButton.Disabled  = False
  262. 	ResetButton.Disabled = False
  263.  
  264. 	' Change mouse pointer back to default
  265. 	Document.Body.Style.Cursor = "default"
  266. End Sub
  267.  
  268.  
  269. Sub PasteClipboardDateFilter
  270. 	FilterDateTextBox.Value = Document.ParentWindow.ClipboardData.GetData( "text" )
  271. End Sub
  272.  
  273.  
  274. Sub PasteClipboardNameFilter
  275. 	FilterNameTextBox.Value = Document.ParentWindow.ClipboardData.GetData( "text" )
  276. End Sub
  277.  
  278.  
  279. Sub PasteClipboardPC
  280. 	ComputerNameTextBox.Value = Document.ParentWindow.ClipboardData.GetData( "text" )
  281. End Sub
  282.  
  283.  
  284. Sub PasteClipboardVendorFilter
  285. 	FilterVendorTextBox.Value = Document.ParentWindow.ClipboardData.GetData( "text" )
  286. End Sub
  287.  
  288.  
  289. Sub RestoreWindowSize( )
  290. 	If blnUpdate Then
  291. 		intUpdateSize = 200
  292. 	Else
  293. 		intUpdateSize = 0
  294. 	End If
  295. 	' Disabled error handling to prevent an error message but no error when the window is resized by doubleclicking the title bar
  296. 	On Error Resume Next
  297. 	WindowSize intWindowWidth, intWindowHeight + intUpdateSize
  298. 	On Error Goto 0
  299. End Sub
  300.  
  301.  
  302. Function TextFromHTML( myURL )
  303.     Dim objHTTP
  304.     TextFromHTML = ""
  305.     Set objHTTP = CreateObject( "WinHttp.WinHttpRequest.5.1" )
  306.     objHTTP.Open "GET", myURL
  307.     objHTTP.Send
  308.     ' Check if the result was valid, and if so return the result
  309.     If objHTTP.Status = 200 Then
  310.     	TextFromHTML = objHTTP.ResponseText
  311.     End If
  312.     Set objHTTP = Nothing
  313. End Function
  314.  
  315.  
  316. Sub Window_Onload
  317. 	WindowSize 1024, 840
  318. 	document.title = SoftInv.ApplicationName & ",  Version " & SoftInv.Version & "  -  " & CopyRights & " Rob van der Woude"
  319. 	ComputerNameTextBox.ReadOnly     = False
  320. 	ComputerNameTextBox.Value        = ""
  321. 	ResultsTextArea.Value            = ""
  322. 	ResultsHiddenText.Value          = ""
  323. 	FilterNameTextBox.ReadOnly       = False
  324. 	FilterNameTextBox.Value          = ""
  325. 	FilterVendorTextBox.ReadOnly     = False
  326. 	FilterVendorTextBox.Value        = ""
  327. 	FilterDateTextBox.ReadOnly       = False
  328. 	FilterDateTextBox.Value          = ""
  329. 	WindowsTextBox.Value             = ""
  330. 	SPTextBox.Value                  = ""
  331. 	CopyButton.Disabled              = True
  332. 	PasteButtonPC.disabled           = False
  333. 	PasteButtonPC.Disabled           = False
  334. 	PasteButtonNameFilter.Disabled   = False
  335. 	PasteButtonVendorFilter.Disabled = False
  336. 	PasteButtonDateFilter.Disabled   = False
  337. 	RunButton.Disabled               = False
  338. 	ResetButton.Disabled             = False
  339. 	AppVersion.InnerHTML             = SoftInv.Version
  340. 	ComputerNameTextBox.Focus( )
  341. 	window.setTimeout "CheckUpdate( )", 100
  342. End Sub
  343.  
  344.  
  345. Sub WindowSize( intWidth, intHeight )
  346. 	On Error Resume Next
  347. 	Dim posWidth, posHeight
  348. 	If intWidth  > window.screen.width  Then intWidth  = window.screen.width
  349. 	If intHeight > window.screen.height Then intHeight = window.screen.height
  350. 	posWidth  = ( window.screen.width  - intWidth  ) / 2
  351. 	posHeight = ( window.screen.height - intHeight ) / 2
  352. 	If posWidth  < 0 Then posWidth  = 0
  353. 	If posHeight < 0 Then posHeight = 0
  354. 	window.resizeTo intWidth, intHeight
  355. 	window.moveTo posWidth, posHeight
  356. 	On Error GoTo 0
  357. End Sub
  358.  
  359.  
  360. Sub WinVer( strComputer )
  361. 	Dim colItems, objItem, objWMIService
  362. 	On Error Resume Next
  363. 	Set objWMIService = GetObject( "winmgmts://" & strComputer & "/root/cimv2" )
  364. 	If Err Then
  365. 		ComputerNameTextBox.Style.backgroundColor = clrBgErr
  366. 		ComputerNameTextBox.Style.Color           = clrTxtErr
  367. 		ComputerNameTextBox.Focus( )
  368. 		Err.Clear
  369. 		On Error GoTo 0
  370. 		EditQuery( )
  371. 		Exit Sub
  372. 	End If
  373. 	Set colItems = objWMIService.ExecQuery("Select * from Win32_OperatingSystem",,48)
  374. 	If Err Then
  375. 		ComputerNameTextBox.Style.backgroundColor = clrBgErr
  376. 		ComputerNameTextBox.Style.Color           = clrTxtErr
  377. 		ComputerNameTextBox.Focus( )
  378. 		Err.Clear
  379. 		On Error GoTo 0
  380. 		EditQuery( )
  381. 		Exit Sub
  382. 	End If
  383. 	For Each objItem in colItems
  384. 		WindowsTextBox.Value = Split( objItem.Caption, " ", 2, vbTextCompare )(1)
  385. 		SPTextBox.Value      = objItem.CSDVersion
  386. 	Next
  387. 	On Error GoTo 0
  388. End Sub
  1. </script>
  2.  
  3. <body>
  4.  
  5. <div class="Center">
  6.  
  7. <span id="Update">&nbsp;</span>
  8.  
  9. <table class="Center">
  10. <tr>
  11.     <th class="Right">Computer Name:</th>
  12.     <td>&nbsp;&nbsp;&nbsp;</td>
  13.     <td class="Center"><input type="text" name="ComputerNameTextBox" size="20" title="Fill in a remote computer name or leave this field blank to query the local computer."></td>
  14.     <td>&nbsp;&nbsp;&nbsp;</td>
  15.     <td class="Left"><input id="PasteButtonPC" class="Button" type="button" value="Paste" name="PasteButtonPC" onclick="PasteClipboardPC" title="Click here to paste a remote computer name from the clipboard into the Computer Name field."></td>
  16. </tr>
  17. <tr>
  18.     <th class="Right">Windows Version:</th>
  19.     <td>&nbsp;&nbsp;&nbsp;</td>
  20.     <td class="Center"><input name="WindowsTextBox" id="WindowsTextBox" size="20" readonly="readonly" title="This read-only field will display the Windows version."></td>
  21.     <td colspan="2">&nbsp;&nbsp;&nbsp;</td>
  22. </tr>
  23. <tr>
  24.     <th class="Right">ServicePack:</th>
  25.     <td>&nbsp;&nbsp;&nbsp;</td>
  26.     <td class="Center"><input name="SPTextBox" id="SPTextBox" size="20" readonly="readonly" title="This read-only field will display Windows' latest installed ServicePack."></td>
  27.     <td colspan="2">&nbsp;&nbsp;&nbsp;</td>
  28. </tr>
  29. <tr>
  30.     <td colspan="5">&nbsp;</td>
  31. </tr>
  32. <tr>
  33.     <td colspan="2">&nbsp;</td>
  34.     <th class="Center">Filters:</th>
  35.     <td colspan="2">&nbsp;</td>
  36. </tr>
  37. <tr>
  38.     <th class="Right">Name:</th>
  39.     <td>&nbsp;&nbsp;&nbsp;</td>
  40.     <td class="Center"><input name="FilterNameTextBox" id="FilterNameTextBox" size="20" title="Use this field to limit the output to only software with the filter string in its NAME value."></td>
  41.     <td>&nbsp;&nbsp;&nbsp;</td>
  42.     <td class="Left"><input name="PasteButtonNameFilter" id="PasteButtonNameFilter" class="Button" type="button" value="Paste" onclick="PasteClipboardNameFilter" title="Click here to paste a filter string from the clipboard into the Name Filter field."></td>
  43. </tr>
  44. <tr>
  45.     <th class="Right">Vendor:</th>
  46.     <td>&nbsp;&nbsp;&nbsp;</td>
  47.     <td class="Center"><input name="FilterVendorTextBox" id="FilterVendorTextBox" size="20" title="Use this field to limit the output to only software with the filter string in its VENDOR value."></td>
  48.     <td>&nbsp;&nbsp;&nbsp;</td>
  49.     <td class="Left"><input name="PasteButtonVendorFilter" id="PasteButtonVendorFilter" class="Button" type="button" value="Paste" onclick="PasteClipboardVendorFilter" title="Click here to paste a filter string from the clipboard into the Vendor Filter field."></td>
  50. </tr>
  51. <tr>
  52.     <th class="Right">Install Date:</th>
  53.     <td>&nbsp;&nbsp;&nbsp;</td>
  54.     <td class="Center"><input name="FilterDateTextBox" id="FilterDateTextBox" size="20" title="Use this field to display only software installed at the specified date or later. Date should be in YYYYMMDD format."></td>
  55.     <td>&nbsp;&nbsp;&nbsp;</td>
  56.     <td class="Left"><input name="PasteButtonDateFilter" id="PasteButtonDateFilter" class="Button" type="button" value="Paste" onclick="PasteClipboardDateFilter" title="Click here to paste a filter date from the clipboard into the Install Date Filter field."></td>
  57. </tr>
  58. <tr>
  59.     <td colspan="5">&nbsp;</td>
  60. </tr>
  61. <tr>
  62.     <td colspan="5">&nbsp;</td>
  63. </tr>
  64. <tr>
  65.     <td colspan="5" class="Center"><textarea name="ResultsTextArea" id="ResultsTextArea" rows="15" cols="80" readonly="readonly" title="This read-only field will display all software that has been installed by Windows' Installer."></textarea></td>
  66. </tr>
  67. <tr>
  68.     <td colspan="5">&nbsp;</td>
  69. </tr>
  70. <tr>
  71.     <td colspan="5"><input type="hidden" name="ResultsHiddenText" id="ResultsHiddenText"></td>
  72. </tr>
  73. <tr>
  74. 	<td class="Right"><input id="RunButton" class="Button" type="button" value="Go" name="RunButton" onclick="window.setTimeout 'Inventory', 1" title="Click here to start the inventory"></td>
  75.     <td>&nbsp;&nbsp;&nbsp;</td>
  76. 	<td class="Center"><input id="CopyButton"  class="Button" type="button" value="Copy"  name="CopyButton"  onclick="CopyClipboard" title="Click here to copy the results to the clipboard. The data in the clipboard will be in tab delimited format. Paste the data in a spreadsheet, using tab as the only delimiter, to create reports."></td>
  77.     <td>&nbsp;&nbsp;&nbsp;</td>
  78. 	<td class="Left"><input id="ResetButton" class="Button" type="button" value="Reset" name="ResetButton" onclick="Location.Reload(True)" title="Click here to clear all fields"></td>
  79. </tr>
  80. </table>
  81.  
  82. <p>&nbsp;</p>
  83.  
  84. <p class="Center">
  85.  
  86. <p class="Center">Software Inventory,  Version <span id="AppVersion">0.00</span><br>
  87. <span style="font-size: 80%;">&copy; 2005 - 2013, Rob van der Woude<br>
  88. <a href="http://www.robvanderwoude.com/software.php"><span class="Red">http://www.robvanderwoude.com</span></a></span></p>
  89.  
  90. <p class="Center" style="font-size: 80%;">Created using the Microsoft Scripting Guys'
  91. <a href="http://www.microsoft.com/technet/scriptcenter/tools/scripto2.mspx" class="Red">Scriptomatic 2.0</a> and
  92. <a href="http://www.microsoft.com/downloads/details.aspx?FamilyId=231D8143-F21B-4707-B583-AE7B9152E6D9&displaylang=en" class="Red">HTA Helpomatic</a>
  93. tools.</p>
  94.  
  95. <p>&nbsp;</p>
  96.  
  97. </div>
  98.  
  99. </body>
  100. </html>

page last uploaded: 2017-07-06, 12:37