Unattended Installation Procedures

Install:

Obtain a free license to redistribute the software on your local network.

Download the Flash Player(s) for your browser(s), the URL will be sent by e-mail.

Install the downloaded .MSI file like any other .MSI:

    SET MSIArgs=/qn /norestart REBOOT=ReallySuppress
    MSIEXEC.EXE /I install_flash_player_active_x.msi %MSIArgs% /l install_flash_ie.log
    MSIEXEC.EXE /I install_flash_player_plugin.msi   %MSIArgs% /l install_flash.log

Note:

Many people, including myself, had trouble downloading the most recent Flash player for Internet Explorer from Adobe's Flash download page. In that case, try the download link for the executable installer on Adobe's Troubleshoot Adobe Flash Player installation for Windows page.

Uninstall:

Before installing the new Flash Player, first remove the old one(s), before they become a security risk.
Download uninstall_flash_player.exe and issue the following command:

    uninstall_flash_player.exe /s

To uninstall just one (recent) version, you can also use the general MSI uninstall procedure.

Install:

Preferred method:

First complete the Adobe Reader Distribution Agreement which allows you to redistribute the software on your local network.

Next, download the redistributable version of Adobe Reader. The URL will be sent with the license.

Then use the Adobe Customization Wizard 8 to create a customized MST file.

And finally, install Adobe Reader using SETUP.EXE, without any command line switches. The customizations are stored in the .MST file, and the .INI file will tell setup to use that .MST file.

Alternative method:

download Adobe Reader.

Then install it using the following command line switches:

/sAll

Silent Mode for product

/sPB

Silent Mode with Progress Bar for product

/rs

Reboot Suppress

/rps

Reboot Prompt Suppress

/ini "path"

Alternative initialization file

/sl "language_id"

Set Language; language_id - Code in decimal digits

/l

Enable Error Logging

/msi[command line]

Parameters for MSIEXEC

Silent installation command for Adobe Reader 8.11 US (without logging and without reboot):

    SET MSIArgs=/qn /norestart REBOOT=ReallySuppress
    AdbeRdr811_en_US.exe /sAll /msi"%MSIArgs%"

Install:

Unattended or silent Java installations may seem confusing, as the documented command line switches simply don't seem to work.

Combined with the info I found at unattended.sourceforge.net however, I finally managed to install Java silently with the following command line:

    SET MSIArgs=/qn /norestart REBOOT=ReallySuppress
    SET MSIComp=ADDLOCAL=jrecore IEXPLORER=1 MOZILLA=1 JAVAUPDATE=0 WEBSTARTICON=0
    START /WAIT jre_package.exe /s /a /s /sms /v"%MSIArgs% %MSIComp%"

Note that some of the command line switches are case sensitive.
Read the information at unattended.sourceforge.net for more details on the first couple of switches, as well as the information at java.sun.com for more details on the Java specific switches (the ones in capitals in the quoted part of the command line).

Update:

For some Java versions you may have to remove the /s /a /s /sms command line arguments. Just try the commands on the command line. If any of the arguments is invalid you'll get an error message telling you which one. If you had to remove /s /a /s /sms then you are dealing with a packaged .MSI and only the /qn /norestart... switches are required, without the quotes and without the /v switch. The same is often true if the Windows Installer help pops up (or you made a typo in the .MSI switches):

Install:

First download the appropriate language version.

Move the downloaded executable to an empty directory and unpack it.
Unfortunately, unless you opt for SendKeys, there is no "unattended" command to unpack.
You can specify the directory where the unpacked files should be sent to, by using the /D switch (case sensitive):

    OOo_2.4.0_Win32Intel_install_wJRE_en-US.exe /D=d:\destinationdirectory

Just click Next, change the destination directory if you didn't do so already on the command line, click Unpack, Cancel, Yes, Finish.
You now have a folder named d:\destinationdirectory where the unpacked files are stored.
You can start writing your own silent installation script:

    SET MSIArgs=/qn /norestart REBOOT=ReallySuppress
    SET MSIComp=ADDLOCAL=ALL SELECT_WORD=1 SELECT_EXCEL=1 SELECT_POWERPOINT=1
    START /WAIT MSIEXEC.EXE /I openofficeorg24.msi %MSIArgs% %MSIComp%

Or with a little more "control":

    @ECHO OFF
    SETLOCAL
    :: Find registered Windows user and company name
    FOR /F "tokens=*" %%A IN ('WMIC.EXE OS Get Organization^,RegisteredUser /Format:List') DO (
        SET %%A>NUL
    )
    :: Move to the correct location; modify if this batch file is
    :: not located in the same directory with the OpenOffice .MSI
    PUSHD "%~dp0"
    :: No user interface, no reboot, logging enabled
    SET MSIArgs=/qn /norestart REBOOT=ReallySuppress /L OpenOffice.log
    :: Install everything
    SET MSIComp=ADDLOCAL=ALL
    :: Associate Writer with .DOC and Calc with .XLS extensions
    SET MSIComp=%MSIComp% SELECT_WORD=1 SELECT_EXCEL=1
    :: Do NOT associate Impress with .PPT
    SET MSIComp=%MSIComp% SELECT_POWERPOINT=0
    :: Use registered Windows user and company name, if defined
    IF NOT "%RegisteredUser%"=="" SET MSIUser=USERNAME="%RegisteredUser%"
    IF NOT "%Organization%"==""   SET MSIUser=%MSIUser% COMPANYNAME="%Organization%"
    :: Run the installation
    START /WAIT MSIEXEC.EXE /I openofficeorg24.msi %MSIArgs% %MSIComp% %MSIUser%
    :: Done
    POPD
    ENDLOCAL

More information on command line arguments for the MSI package can be found at the Automatic Installation of OpenOffice.org page.

Install:

I haven't figured out yet how to silently install the WordPerfect Office Suite 12 itself. However, this install command for the servicepacks will at least prevent 2 reboots.

First download the appropriate patches for your language version.
For the English version these are WP12SP1E.msp, WP12SP2EN.msp and WP12SP3EN.msp.

Move the downloads to their intended location, and write a batch file containing the following code, and place it in the same location:

    START /WAIT MSIEXEC.EXE /update WP12SP1E.msp;WP12SP2EN.msp;WP12SP3EN.msp /qn /norestart REBOOT=ReallySuppress

Note:

This procedure is identical for other patches to other software, as long as the patches are in .MSP format.

Install:

KL Software's "low-resource" media players QuickTime Alternative and Real Alternative can be downloaded in a proprietary installer format that allows us to create our own unattended setup using the -MakeUnattended switch:

    quicktimealt251.exe -MakeUnattended

or:

    realalt180.exe -MakeUnattended

Note:

These setup file names were the most recent versions at the time of writing, they may be updated any time soon.

A wizard called "Unattended Install Maker" will appear.
Follow the instructions given in the wizard.

When finished, a batch file and .INI file will be created in the directory where the original setup is located.
Keep the original setup, the batch file and the .INI file all together in one directory, and run the batch file to perform a silent installation with your preselected settings.

Uninstall:

The command:

    CSCRIPT.EXE //NoLogo GetUnins.vbs /F:Alternative

will return the proper uninstall commands.

Uninstall:

To uninstall .MSI packages installed by Windows Installer (MSIEXEC), use my GetUnins.vbs script:

    CSCRIPT //NoLogo drive:\path\GetUnins.vbs /F:"software name"

Find the unistall string for the version you want to uninstall.
The uninstall command may look like this:

    MsiExec.exe /I{ABCD1234-7AA7-1001-1234-987654321ABC}

This is the command for an interactive uninstall or repair!
Change it to a true uninstall command by substituting MSIEXEC.EXE's /I switch with /X, and append the /qn /norestart REBOOT=ReallySuppress switches to make it a silent uninstall without reboot:

    SET MSIArgs=/qn /norestart REBOOT=ReallySuppress
    MSIEXEC.EXE /X{ABCD1234-7AA7-1001-1234-987654321ABC} %MSIArgs%

You may also want to enable logging the uninstall by using the /L switch.
Read more on my MSIEXEC page.