/* Read BIOS date from BIOS */

/* Display blank line */
Say

/* Check for command line parameters (none required) */
Parse Arg strArgs
If strArgs <> "" Then Call Syntax

/* Disable unwanted screen output */
"@ECHO OFF"
Trace Off

/* Initialize variables */
rxCrLf = X2C( 0D0A )
strDbg = "D FFFF:0005 L 8"||rxCrLf||"Q"

/* Define temporary file name */
Parse Source . . strSrc .
filDbg  = SubStr( strSrc, 1, LastPos( ".", strSrc ) ) || "dbg"

/* Create temporary Debug script */
Call LineOut filDbg, strDbg
Call LineOut filDbg

/* Queue the date read from BIOS using Debug script */
"DEBUG < " || filDbg || " | RXQUEUE"

/* Parse the info from the queue */
Do Until Queued( ) = 0
	Parse Pull strDbg
	If Length( strDbg ) > 66 Then strBIOS = SubStr( strDbg, 67 )
End

/* Close and delete temporary Debug script */
Call LineOut filDbg
"DEL " || filDbg || " > NUL"

/* Display result */
Say "BIOS date: "||strBIOS

/* Normal program termination */
Exit 0


Syntax:
	Say "BIOSDate.rex,  Version 1.00"
	Say "Display BIOS date"
	Say
	Say "Usage:  <REXX>  BIOSDATE.REX"
	Say
	Say 'Where:  "<REXX>" is your Rexx interpreter:'
	Say "                 - Windows:  REGINA.EXE or REXX.EXE, whichever you installed"
	Say "                             (tested with Regina Rexx only!)"
	Say "                 - OS/2:     no need to specify, just rename script to *.cmd"
	Say
	Say "This Rexx script uses DEBUG.EXE to read the date from the BIOS"
	Say
	Say "Written by Rob van der Woude"
	Say "http://www.robvanderwoude.com"
	Say
	Say "Original idea by ComputerHope"
	Say "http://www.computerhope.com/rdebug.htm"
	Exit 1
Return