@ECHO OFF
ECHO.
ECHO This script enables WMIC while it is available as a Feature on Demand in Windows 11 24H2.
ECHO In future Windows 11 versions, WMIC may be completely removed, in which case this script
ECHO won't be able to restore it anymore.
ECHO.
PAUSE
ECHO.
ECHO Checking if WMIC is available . . .
WMIC.EXE OS >NUL 2>&1
IF NOT ERRORLEVEL 1 (
	ECHO WMIC is already installed
	EXIT /B 0
)

ECHO Checking OS version . . .
VER | FIND.EXE "10.0.2" >NUL
IF ERRORLEVEL 1 (
	ECHO This batch file is for Windows 11 only
	EXIT /B 1
)

ECHO Checking for elevated privileges . . .
WHOAMI /Groups | FIND "12288" >NUL
IF ERRORLEVEL 1 (
	ECHO This batch file requires elevated privileges
	ECHO Restarting batch file with UAC prompt for elevated privileges . . .
	REM Credits: Evan Greene, https://sites.google.com/site/eneerge/scripts/batchgotadmin
	>  "%temp%\getadmin.vbs" ECHO Set UAC = CreateObject^("Shell.Application"^)
	>> "%temp%\getadmin.vbs" ECHO UAC.ShellExecute "%~s0", "%*", "%~sdp0", "runas", 1
	CSCRIPT.EXE //NoLogo "%temp%\getadmin.vbs"
	EXIT /B 1
)

:: Remove temporary file
IF EXIST "%temp%\getadmin.vbs" DEL "%temp%\getadmin.vbs"

ECHO Installing WMIC . . .
REM Credits: Tiger Technology Knowledge Base, https://kb.tiger-technology.com/wmic_windows_11
PowerShell -c "Add-WindowsCapability -online -name WMIC"