(view source code of scheduld.bat as plain text)
@ECHO OFF
(ECHO.) 1>&2
:: Check for required tool, Windows version, command line arguments
IF NOT [%1]==[] GOTO Syntax
IF NOT "%OS%"=="Windows_NT" GOTO Syntax
VER | FIND "Windows 2000" >NUL
IF ERRORLEVEL 1 GOTO Syntax
STRINGS.EXE >NUL 2>&1
IF ERRORLEVEL 1 GOTO Syntax
:: Display header
(ECHO Scheduled tasks on %ComputerName%:) 1>&2
(ECHO ^(Command, [ Arguments, ] [ Working dir, ] Creator^)) 1>&2
(ECHO.) 1>&2
:: List all tasks and their properties
FOR %%A IN ("%windir%\Tasks\*.job") DO (
ECHO.%%~nA
ECHO.===============================================================================
STRINGS.EXE "%%~fA" | MORE /E +5
)
:: Done
GOTO End
:Syntax
(ECHO Scheduld.bat, Version 1.00 for Windows 2000) 1>&2
(ECHO List all scheduled tasks and some of their properties) 1>&2
(ECHO.) 1>&2
(ECHO Usage: SCHEDULD [ /? ]) 1>&2
(ECHO.) 1>&2
(ECHO Requires SysInternals' STRINGS.EXE, available at) 1>&2
(ECHO http://www.sysinternals.com/ntw2k/source/misc.shtml#Strings) 1>&2
(ECHO.) 1>&2
(ECHO Written by Rob van der Woude) 1>&2
(ECHO http://www.robvanderwoude.com) 1>&2
:End
page last modified: 2024-04-16; loaded in 0.0113 seconds